Jump to content
Son zamanlarda artan kullanıcı hesap hırsızlıkları sebebiyle tüm kullanıcılara şifre sıfırlama maili gönderilmiştir. Lütfen güveli şifreler seçiniz. Mevcut e-mail adresinize erişemiyorsanız, en aşağıdaki destek linkinden bize ulaşınız. ×

Resimi Web Sayfasinda Acmak


Skorpion
 Share

Recommended Posts

Selam Arkadaslar,

ben almanyada bir is yerinde ustabasiyim

ve bu aralar almanca bilmeyen cesitli ülkelerden isciler geliyor

ben yeni ise baslayan kisilere  pcde egitim vermem gerekiyor bende cözümü resimleri googletranslate ile tercüme etirmek ile buldum

yanliz bunu biraz kolaylastirmak istiyorum her seferinde sayfayi kapatip diger resimi göstermek ugrastiriyor veya sirasini karistirabiliyorsun

ben söyle birsey ypmak istiyorum

desktopda egitim 1 adli klasörde 45 tane resim var bunlari bir skript ile sirayla web sayfasinda actirmak istiyorum

https://translate.google.de/?sl=de&tl=tr&op=images

bir tus ileri gidecek digeri geri böyle birsey yapmak mümkünmü acaba.

Saygilar

 

Link to comment
Share on other sites

Selam @Skorpion Arkadaşım!

Aşağıdaki kodları oluşturdum. Ama kendi bilgisayarıma göre koordinat ve bekleme süreleri içeriyor. Senin bu kodları gözden geçirip kendi bilgisayarına göre düzenlemen/uyarlaman gerekiyor. 

Kod :

;~ 26.04.2023 - [NUH21TR]
;~ Autoit v3.3.16.1
;~ Win 11'de denendi.

;~ Dikkat!!!
;~ Buradaki kodlarda belirtilen koordinatlar ve işlemler arası gerekli bekleme süreleri kendi PC'nizde farklılık gösterebilir.
;~ Buradaki kodlar istemsiz tıklamalara sebep olabilir.
;~ Sorumluluk buradaki kodu çalıştarana aittir.
;~ Bu sebeple kodu çalıştırmadan önce gözden geçiriniz!


#include <File.au3>
#include <MsgBoxConstants.au3>
#include <AutoItConstants.au3>


MsgBox("", "Tuşlar", "{SAĞ YÖN TUŞU}  •  Bir sonraki resmi açar." & @CRLF & @CRLF & _
		"{SOL YÖN TUŞU}  •  Bir önceki resmi açar." & @CRLF & @CRLF & _
		"{ESC}  •  Programdan çıkış yapar." & @CRLF & @CRLF & _
		"• Bu mesaj kutusundan sonra resimlerin bulunduğu klasörü seçin." & @CRLF & _
		"• Çeviri ilk dosya için otomatik işlenecek sonra belirtilen tuşlar ile yönlendirebileceksiniz.")

Local $sResimlerinBulunduguKlasorAdresi = FileSelectFolder("Dili Çevrilecek Resimlerin Bulunduğu Klasörü Seç", @ScriptDir)

Global Const $sGoogleTranslateSayfasi = "https://translate.google.de/?sl=de&tl=tr&op=images"
Global Const $iDosyaTanimlaYatayKoordinat = 1270, $iDosyaTanimlaDikeyKoordinat = 425 ; 1270,425 - >> Translate sayfasındaki "Bilgisayarınıza gözatın" tuşuna tıklatmak için.
Global Const $iResmiTemizleYatayKoordinat = 1880, $iResmiTemizleDikeyKoordinat = 308 ; 1880,308 - >> Translate sayfasındaki "Resmi Temizle (X)" tuşuna tıklatmak için.
Global $iIslemlerArasiBeklemeSuresi_Milisaniye = 1000 ; Dosyaların işlenme-yüklenme hızına bağlı olarak değiştirebilirsiniz.
Global $aResimlerinSiraliListesi = _FileListToArrayRec($sResimlerinBulunduguKlasorAdresi, "*.jpg;*.jpeg;*.png", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_RELPATH)
Global $iToplamResimSayisi = $aResimlerinSiraliListesi[0] ; $aResimlerinSiraliListesi[0] >> (Listedeki Toplam Dosya Sayısını Verir.)
Global $iMevcutResimSirasi = 1
Global $bTarayiciIcinKlasorYeriTanimlanmisMi = False

HotKeySet("{LEFT}", "nvOncekiResmiAc")
HotKeySet("{RIGHT}", "nvSonrakiResmiAc")
HotKeySet("{ESC}", "Cikis")

nvGoogleTranslateResimDiliniCevir($aResimlerinSiraliListesi[$iMevcutResimSirasi])

While 1
	Sleep(50)
WEnd

Func nvGoogleTranslateResimDiliniCevir($sDosyaAdi)

	If $bTarayiciIcinKlasorYeriTanimlanmisMi = False Then

		ShellExecute($sGoogleTranslateSayfasi)

	EndIf

	Sleep($iIslemlerArasiBeklemeSuresi_Milisaniye)

	If Not WinActive("Google Çeviri - Google Chrome") Then WinActivate("Google Çeviri - Google Chrome")
	MouseClick($MOUSE_CLICK_LEFT, $iDosyaTanimlaYatayKoordinat, $iDosyaTanimlaDikeyKoordinat, 1, 0)

	Sleep($iIslemlerArasiBeklemeSuresi_Milisaniye)

	If $bTarayiciIcinKlasorYeriTanimlanmisMi = False Then

		ControlClick("Aç", "Üst şerit", "[CLASS:ToolbarWindow32; INSTANCE:3]")
		Send($sResimlerinBulunduguKlasorAdresi)
		Send("{Enter}")

		$bTarayiciIcinKlasorYeriTanimlanmisMi = True

		$iIslemlerArasiBeklemeSuresi_Milisaniye = 500

	EndIf

	ControlClick("Aç", "Üst şerit", "[CLASS:Edit; INSTANCE:1]")
	Sleep(50)

	Send($sDosyaAdi)
	Sleep($iIslemlerArasiBeklemeSuresi_Milisaniye)
	Send("{Enter}")
	Sleep(50)

EndFunc   ;==>nvGoogleTranslateResimDiliniCevir


Func nvOncekiResmiAc()

	If Not WinActive("Google Çeviri - Google Chrome") Then WinActivate("Google Çeviri - Google Chrome")
	MouseClick($MOUSE_CLICK_LEFT, $iResmiTemizleYatayKoordinat, $iResmiTemizleDikeyKoordinat, 1, 0)
	If $iMevcutResimSirasi <> 1 Then $iMevcutResimSirasi -= 1
	nvGoogleTranslateResimDiliniCevir($aResimlerinSiraliListesi[$iMevcutResimSirasi])
;~ 	If WinActive("Google Çeviri - Google Chrome") Then Send("^w")

EndFunc   ;==>nvOncekiResmiAc


Func nvSonrakiResmiAc()

	If Not WinActive("Google Çeviri - Google Chrome") Then WinActivate("Google Çeviri - Google Chrome")
	MouseClick($MOUSE_CLICK_LEFT, $iResmiTemizleYatayKoordinat, $iResmiTemizleDikeyKoordinat, 1, 0)
	If $iMevcutResimSirasi <> $iToplamResimSayisi Then $iMevcutResimSirasi += 1
	nvGoogleTranslateResimDiliniCevir($aResimlerinSiraliListesi[$iMevcutResimSirasi])
;~ 	If WinActive("Google Çeviri - Google Chrome") Then Send("^w")

EndFunc   ;==>nvSonrakiResmiAc


Func Cikis()
	Exit
EndFunc   ;==>Cikis

 

[NUH21TR].

 

Edited by nuh21tr
  • Thanks 1
Link to comment
Share on other sites

Cok tesekkür ederim ustam yarin is yerinde deniyecegim

Efsanesin .

Galiba kordinatlarla ilgili bir sorunum var sayfayi maximal boyuta alip denemeye calisacagim

(bugün isler yogun oldugundan fazla zaman ayiramadim )

cok emek vermissin @nuh21tr arkadasim ugrastirdim seni

Varol

 

Edited by Skorpion
  • Thanks 1
Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

 Share

  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...