Win7 Logon Ekranı Değiştirici

[DivaneTR]

[center][b]Windows 7 Logon Ekranı Değiştirici[/b][/center]


[center][img]http://i.imgur.com/fqb4n.png[/img][/center]

[center] [/center]
[center][code]http://www.mediafire.com/download.php?4oo5dznj6wxtae8[/code][/center]

[b]Script :[/b]
[spoiler]
[codebox]
#NoTrayIcon
; Script : Logon Ekrani Degistirici
; Kodlama : -Divane-
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <Process.au3>
; Arayuzu Olusturalim
$Form1 = GUICreate("Logon Ekranı Değiştirici", 570, 440, -1, -1)
$Tab1 = GUICtrlCreateTab(25, 8, 520, 377)
$TabSheet1 = GUICtrlCreateTabItem("Değiştir")
$Drag = GUICtrlCreatePic("", 45, 45, 480, 320, Default)
$TabSheet2 = GUICtrlCreateTabItem("Hakkında")
$Label1 = GUICtrlCreateLabel("Divane Presents.", 85, 136, 400, 70)
GUICtrlSetFont(-1, 40, 400, 0, "Trebuchet MS")
$Label2 = GUICtrlCreateLabel("Turkish Network Community", 111, 241, 348, 39)
GUICtrlSetColor(-1, 0x800000)
GUICtrlSetFont(-1, 20, 400, 0, "Trebuchet MS")
GUICtrlCreateTabItem("")
$Button1 = GUICtrlCreateButton("Değiştir", 110, 400, 80, 25)
$Button2 = GUICtrlCreateButton("Orjinale Dön", 240, 400, 80, 25)
$Button3 = GUICtrlCreateButton("Test Et", 370, 400, 80, 25)
GUISetState(@SW_SHOW)
; Onceki Logon Ekranini Kontrol Edelim.
If FileExists("C:\WINDOWS\system32\oobe\info\backgrounds\backgroundDefault.jpg") Then
GUICtrlSetImage($Drag, "C:\WINDOWS\system32\oobe\info\backgrounds\backgroundDefault.jpg")
Else
GUICtrlSetImage($Drag, "C:\Windows\System32\oobe\background.bmp")
EndIf

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1 ; Degistir Buttonu
$Sec = FileOpenDialog("Arkaplan Seçiniz..", @DesktopDir,"Görüntü Dosyası(*.jpg)") ; Secim Diyalogu
If Not @error Then ; Eger Secim Yapıldıysa
$Boyut = FileGetSize($Sec) ; Secilen Dosyanin Boyutunu Al
If $Boyut < 250880 Then ; 245 KB'dan Kucuk Ise,
GUICtrlSetImage($Drag, $Sec) ; Resmi Programda Goster
RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Background", "OEMBackground", "REG_DWORD", "00000001") ; Gerekli Ayar
DirCreate("C:\WINDOWS\system32\oobe\info\backgrounds") ; Klasor Olustur
FileCopy($Sec, "C:\WINDOWS\system32\oobe\info\backgrounds\backgroundDefault.jpg",1) ; Secilen Resmi Dizine Kopyala
MsgBox(64,"Divane","Logon Ekranı Başarıyla Değiştirildi !") ; Bilgi Mesaji
Else ; Aksi Takdirde
MsgBox(48,"Divane","Seçilen Resmin Boyutu 245 KB'dan Düşük Olması Gerekir !") ; Uyari Mesaji Ver
EndIf ; Kosullandirmayi Bitir
EndIf ; Kosullandirmayi Bitir
Case $Button2 ; Eski Haline Geri Cevir
RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Background", "OEMBackground", "REG_DWORD", "00000000") ; Gerekli Ayar
DirRemove("C:\WINDOWS\system32\oobe\info",1) ; Olusturulan Dizini ve Alt Klasorleri Sil
GUICtrlSetImage($Drag, "C:\Windows\System32\oobe\background.bmp") ; Varsayilan Resmi Programda Goruntule
MsgBox(64,"Divane","Logon Ekranı Sistem Varsayılanına Dönüştürüldü !") ; Bilgi Mesaji Ver
Case $Button3 ; Test Buttonu ( Oturumu Kapatir )
$Sor = MsgBox(33,"Divane","Logon Ekranın Test Etmek İçin" & @CRLF & "Program Şimdi Oturumu Kapatacak !")
If $Sor = 1 Then ; Eger Onaylanirsa
Run("shutdown /l") ; Oturumu Kapat
EndIf ; Kosullandirmayi Bitir
Case $Label2 ; Turkish Network Community Yazisina Tiklanirsa
_RunDOS("start www.tnctr.com") ; Anasayfaya Git
EndSwitch
WEnd
[/codebox]
[/spoiler]

Edited October 29, 2012 by DivaneTR

[ugur4721]

DİVANE Tr ellerine sağlıkta başka siteye upload edebilirmisin ? link kırık Ondan
bide o tema elinde varsa upload edermisin ?

[DivaneTR]

[font=tahoma,geneva,sans-serif]Link yenilenmiştir.[/font]

[font=tahoma,geneva,sans-serif]Radiance Tema ;[/font]
[CODE]
http://fav.me/d4jybx5
[/CODE]