Buton Ile Döngülerden Çıkma

[Mehmet]

Arkadaşlar döngüler ve değişkenlerde çok takılıyorum butonla bir döngüden çıkmak istiyorum ama bir kaç çeşit döngümüz var ve biz bu döngüleri farklı farklı alanda kullanmak istiyoruz ama hiç birini yapamadım dur butonuna tıkladığımda nasıl döngüden çıkarım anlaşılır ve sade bir şekilde anlatacak bir arkadaşımız yardım edebilirmi

[b]Do-Until[/b]

[codebox]
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 153, 193, 192, 124)
$basla = GUICtrlCreateButton("Başlat", 32, 40, 75, 25)
$dur = GUICtrlCreateButton("Dur", 32, 96, 75, 25)
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $basla
$deneme1 = 0
Do
MsgBox(0, "dur butonu yokmu ", $deneme1)
$deneme1 = $deneme1 + 1
Until $deneme1 = 0 ;örneğin burada 0 değerini verdik ama hiçbirzaman 0 olmayacağına göre sürekli sayacak bu döngüden butonla çıkmak istiyorum
EndSwitch
WEnd[/codebox]

[b]For[/b]

[codebox]#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 153, 193, 192, 124)
$basla = GUICtrlCreateButton("Başlat", 32, 40, 75, 25)
$dur = GUICtrlCreateButton("Dur", 32, 96, 75, 25)
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $basla
For $on = 1 to 100 Step 1
MsgBox(0,"100'ekadar saymadan durdurun beni ", $on)
Next
EndSwitch
WEnd[/codebox]

[b]While[/b]

[codebox]#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 153, 193, 192, 124)
$basla = GUICtrlCreateButton("Başlat", 32, 40, 75, 25)
$dur = GUICtrlCreateButton("Dur", 32, 96, 75, 25)
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $basla
While 2
ClipPut("butonsuz duramam ")
Send("^v")
Wend
EndSwitch
WEnd[/codebox]

[blue_life]

@MeHMeTBeN

Verdiğin örnekleri, tek bir örnekte veriyorum. Yani Başlata bastığında sırasıyla üç döngüyede girecek. Dur ile çıkabilirsin... Inceleyiniz...

[codebox]Global $DONGU = True ;Döngüdeyken bu değer false ise döngüden çıkalım

Global $Form1 = GUICreate("Form1", 153, 193, 192, 124)
Global $basla = GUICtrlCreateButton("Başlat", 32, 40, 75, 25)
Global $dur = GUICtrlCreateButton("Dur", 32, 96, 75, 25)

GUIRegisterMsg(273, "MY_WM_COMMAND") ;Registermsg

GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
Case $basla
$DONGU = True ;Döngüyü true yapalım
$deneme1 = 0
Do
MsgBox(0, "dur butonu yokmu ", $deneme1)
$deneme1 = $deneme1 + 1
Until $DONGU = False ;DONGU değişkeni false olana kadar devam edelim

; --------------------------

$DONGU = True ;Döngüyü true yapalım
For $on = 1 To 100 Step 1
MsgBox(0, "100'ekadar saymadan durdurun beni ", $on)
If $DONGU = False Then ExitLoop ;DONGU false ise çıkalım
Next

; --------------------------

$DONGU = True ;Döngüyü true yapalım
While $DONGU = True ; DONGU true iken devam edelim
ClipPut("butonsuz duramam ")
Send("^v")
Sleep(50)
WEnd
EndSwitch
WEnd
Func MY_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
Switch BitAND($wParam, 0x0000FFFF)
Case $dur
$DONGU = False ;Değeri false yapalım
EndSwitch
Return "GUI_RUNDEFMSG"
EndFunc ;==>MY_WM_COMMAND[/codebox]

[daft117]

al en basit haliyle bir örnek

$a=1
while $a=1 ;$a=1 olduğu sürece döngü devam edecek.
$yazi="yaz bişiler işte"
if Butona Basıldıysa Then
$a=0 ;veya ne istersen yeterki 1 olmasın
endif
wend

Edited April 29, 2012 by daft117