Buyrun Arkadaşlar Gif Form Resimli Müzikli

[selamdostum]

[size="6"][color="#FF0000"]Müzik eklenmiştir.[/color][/size]
[img]http://www.karanliksehir.com/programlar/X-VirusGIFForm.jpg[/img]

Kodlar

[code]
#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Version=beta
#AutoIt3Wrapper_Icon=X-Virus\X-Virus2.ico
#AutoIt3Wrapper_Outfile=X-VirusGIFForm.exe
#AutoIt3Wrapper_Compression=0
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Res_Comment=Kurulum bitmiştir...
#AutoIt3Wrapper_Res_Description=][ X-Virus ][
#AutoIt3Wrapper_Res_Fileversion=2.0.1.2
#AutoIt3Wrapper_Res_LegalCopyright=][ X-Virus ][ ™
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <Misc.au3>
#include <WinAPI.au3>
#include <File.au3>
Global $ScriptDir = @ScriptDir
FileInstall("X-Virus.gif", @Tempdir&"\X-Virus.gif",1)
FileInstall("X-Virus.mp3", @Tempdir&"\X-Virus.mp3",1)

HotKeySet("{Esc}", "Quit")
HotKeySet("{Left}", "Left")
HotKeySet("{Right}", "Right")
HotKeySet("{Pause}", "Pause")

SoundPlay(@TempDir & "\X-Virus.mp3")
SoundSetWaveVolume(100)
Global $Gif = @TempDir & "\X-Virus.gif"
Global $i = 0, $ApX, $ApY, $ApW, $ApH, $eX, $eY
Global $hImage, $hBitmap, $hScrDC, $hMemDC, $tSize, $pSize, $tSource, $pSource, $tBlend, $pBlend
Global $GFC, $GFDC, $pDimensionIDs, $tDL
Global $Pause

$hGUI = GUICreate("", Default, Default, 900, 650, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOOLWINDOW))
WinSetOnTop($hGUI, "", 1) ;--> Burayı aktifleştiriseniz her zaman üstte kalacaktır.

GUISetState()

GifInit()
While 1

If $i = $GFC Then $i = 0
GifDrawFrame($i)

Sleep(100)

$i += 1

WEnd


Func Quit()
_GDIPlus_ImageDispose($hImage)
_WinAPI_ReleaseDC(0, $hScrDC)
_WinAPI_DeleteObject($hBitmap)
_WinAPI_DeleteDC($hMemDC)
_GDIPlus_Shutdown()

HotKeySet("{Esc}")
HotKeySet("{Left}")
HotKeySet("{Right}")
HotKeySet("{Pause}")

Exit
EndFunc

Func GifInit()
_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile($Gif)
$ApW = _GDIPlus_ImageGetWidth($hImage)
$ApH = _GDIPlus_ImageGetHeight($hImage)

$hScrDC = _WinAPI_GetDC($hGUI)
$hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)

$tSize = DllStructCreate($tagSIZE)
DllStructSetData($tSize, "X", $ApW)
DllStructSetData($tSize, "Y", $ApH)
$pSize = DllStructGetPtr($tSize)

$tSource = DllStructCreate($tagPOINT)
$pSource = DllStructGetPtr($tSource)

$tBlend = DllStructCreate($tagBLENDFUNCTION)
DllStructSetData($tBlend, "Alpha", 255)
DllStructSetData($tBlend, "Format", 1)
$pBlend = DllStructGetPtr($tBlend)

$tDL = DllStructCreate($tagGUID)

$pDimensionIDs = DllStructGetPtr($tDL)

$GFDC = DllCall($ghGDIPDll, "int", "GdipImageGetFrameDimensionsCount", "ptr", $hImage, "int*", 0)

DllCall($ghGDIPDll, "int", "GdipImageGetFrameDimensionsList", "ptr", $hImage, "ptr", $pDimensionIDs, "int", $GFDC[2])

$GFC = DllCall($ghGDIPDll, "int", "GdipImageGetFrameCount", "int", $hImage, "ptr", $pDimensionIDs, "int*", 0)
$GFC = $GFC[3]
EndFunc

Func GifDrawFrame($i)
DllCall($ghGDIPDll, "int", "GdipImageSelectActiveFrame", "ptr", $hImage, "ptr", $pDimensionIDs, "int", $i)

$hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
$hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)

_WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)


EndFunc

Func FlyUfo()
Local $Speed = 0
Do
If $ApX >= (@DesktopWidth - $ApW) Then
$eX = "$ApX - 1"
ElseIf $ApX <= 0 Then
$eX = "$ApX + 1"
EndIf
If $ApY >= (@DesktopHeight - $ApH) Then
$eY = "$ApY - 1"
ElseIf $ApY <= 0 Then
$eY = "$ApY + 1"
EndIf
$ApX = Execute($eX)
$ApY = Execute($eY)
WinMove($hGUI, "", $ApX, $ApY)
$Speed += 1
Until $Speed = 5
EndFunc

Func Left()
If WinActive($hGUI) Then
If Not $Pause Then Return
$i -= 1
If $i = -1 Then $i = $GFC - 1
GifDrawFrame($i)
Else
HotKeySet("{Left}")
Send("{Left}")
HotKeySet("{Left}", "Left")
EndIf
EndFunc

Func Right()
If WinActive($hGUI) Then
If Not $Pause Then Return
$i += 1
If $i = $GFC Then $i = 0
GifDrawFrame($i)
Else
HotKeySet("{Right}")
Send("{Right}")
HotKeySet("{Right}", "Right")
EndIf
EndFunc

Func Pause()
If WinActive($hGUI) Then
$Pause = Not $Pause
If Not $Pause Then Return

While $Pause
Sleep(100)
WEnd
Else
HotKeySet("{PAUSE}")
Send("{PAUSE}")
HotKeySet("{PAUSE}", "Pause")
EndIf
EndFunc
[/code]

Gif resmi

[img]http://www.karanliksehir.com/programlar/X-Virus.gif[/img]

Yada hepsini hazır olarak indir
Gif çalışması psd olarak içindedir...
Esc ile script kapatılır.
[code]http://www.karanliksehir.com/programlar/X-VirusGIFForm.zip[/code]

İsterseniz exe olarak deneyiniz...
[code]http://www.karanliksehir.com/programlar/X-VirusGIFForm.exe[/code] Edited August 6, 2012 by selamdostum